'From Cuis 5.0 [latest update: #4204] on 3 June 2020 at 6:20:45 pm'!

!TerseGuideHelp class methodsFor: 'pages' stamp: 'KenD 6/3/2020 15:31:03'!
layoutSpec
	"Layout Specification"
	^
'| layout ellipse ellipseLayout image interiorLayout rect |
"A LayoutMorph places its submorphs alone the layout axis.
 The submorphs may use a LayoutSpec to specify, for width and height,
 a fixed or porportional extent, a minimum extent, an offAxisEdgeWeight."

"Some Morphs to use"
ellipse _ EllipseMorph initializedInstance.
rect _ BorderedRectMorph initializedInstance.
image _ ImageMorph initializedInstance.
ellipseLayout _ (LayoutSpec proportionalWidth: 0.3 fixedHeight: 60 offAxisEdgeWeight: #rowTop).
ellipseLayout proportionalWidth: 0.5  minimum: 40.
ellipse layoutSpec: ellipseLayout.
rect layoutSpec: (LayoutSpec fixedWidth: 80 proportionalHeight: 0.6 offAxisEdgeWeight: #center).
"Layouts can contain layouts"
interiorLayout _ LayoutMorph newColumn.
interiorLayout separation: 10@20.
interiorLayout layoutSpec: (LayoutSpec proportionalWidth: 0.3 proportionalHeight: 60).
interiorLayout addMorph: EllipseMorph initializedInstance.
interiorLayout addAdjusterAndMorph: (RectangleLikeMorph new) proportionalWidth: 1.0.
"A LayoutMorph to contain them"
layout _ LayoutMorph newRow.
layout addAllMorphs: { ellipse. image. interiorLayout. rect. }.
layout openInWorld.
"Make it bigger"
layout morphExtent: (3 * layout morphExtent).
"Make it colorful"
interiorLayout color: Color cyan.
layout color: Color green lighter lighter.
"add handles; mouse grab lower-right yellow circle with tooltip Change Size."
layout addHalo.
'! !
